@ECHO OFF

SET CERTFILE="SecurEmailLLC.cer"
SET SETUPEXE="setup.exe"
SET CONFIGFILE="config.xml"

IF NOT EXIST %CERTFILE% (
	@ECHO error: %CERTFILE% not found
	GOTO :EOF
)
IF NOT EXIST %SETUPEXE% (
	@ECHO error: %SETUPEXE% not found
	GOTO :EOF
)
IF NOT EXIST %CONFIGFILE% (
	@ECHO error: %CONFIGFILE% not found
	GOTO :EOF
)
REM we need certmgr.exe from Windows SDK or Visual Studio install
WHERE certmgr.exe >nul 2>nul || (
	@ECHO error: certmgr.exe not found
	GOTO :EOF
)

CALL :INSTALL_CERT
CALL :INSTALL_ADDIN
REM wait for setup to create directories
SLEEP 20
CALL :CONFIG_ADDIN
GOTO :EOF

:INSTALL_CERT
REM Install CheckTLS Trusted Publisher certificate
certmgr.exe -add %CERTFILE% -c -s -r localUser TrustedPublisher
EXIT /B

:INSTALL_ADDIN
REM Install the Add-in
%SETUPEXE%
EXIT /B

:CONFIG_ADDIN
CALL :GET_DATAFILES_DIR
MKDIR %DATAFILES_DIR% 2>nul
CALL :COPY_CONFIG_FILE
EXIT /B

:GET_PROGRAMS_DIR
REM ClickOnce programs directory
FOR /F "delims=" %%i IN ('reg query HKCU\Software\Classes\Software\Microsoft\Windows\CurrentVersion\Deployment\SideBySide\2.0 /v ComponentStore_RandomString') DO SET bin=%%i
SET "subdir=%bin:~-24%"
SET "subdir=%subdir:~0,8%.%subdir:~8,3%\%subdir:~11,8%.%subdir:~19,3%"
FOR /F "delims=" %%i in ('dir /B "C:\Users\%USERNAME%\AppData\Local\Apps\2.0/%subdir%\csch..vsto*"') DO set PROGRAMS_DIR=%%i
REM echo %PROGRAMS_DIR%
EXIT /B

:GET_DATAFILES_DIR
CALL :GET_PROGRAMS_DIR
IF [%PROGRAMS_DIR%] == [] (
	@ECHO error: can't locate add-in programs directory
	GOTO :EOF
)
REM ClickOnce datafiles directory
FOR /F "delims=" %%i IN ('reg query HKCU\Software\Classes\Software\Microsoft\Windows\CurrentVersion\Deployment\SideBySide\2.0\StateManager /v StateStore_RandomString') DO set bin=%%i
SET "subdir=%bin:~-24%"
SET "subdir=%subdir:~0,8%.%subdir:~8,3%\%subdir:~11,8%.%subdir:~19,3%"
SET "DATAFILES_DIR=C:\Users\%USERNAME%\AppData\Local\Apps\2.0\Data\%subdir%\%PROGRAMS_DIR%\Data"
REM echo %DATAFILES_DIR%
EXIT /B

:COPY_CONFIG_FILE
REM make CsCheckTLS_OA subdirectory and copy in EmailSentry config file
COPY %CONFIGFILE% %DATAFILES_DIR%\EmailSentry.xml
EXIT /B